تنفيذ اختبارات إحصائية متعددة المتغيرات لعينة واحدة أو عينتين باستخدام SPSS Syntax
DOI:
https://doi.org/10.31272/jae.i144.1233الكلمات المفتاحية:
متعدد المتغيرات لعينة واحدة، متعدد المتغيرات لعينتين، SPSS Syntax، Hotelling’s T2، ، منشئ الحوار المخصصالملخص
غالبًا ما تكون توفر اختبارات المتعددة المتغيرات للعينة الواحدة والعينتين مقيدة أو تتم دمجها مع الاختبارات الإحصائية الأخرى في العديد من التطبيقات الإحصائية. برنامج SPSS المعروف بواجهة المستخدم الصورية (GUI) سهلة الاستخدام للتحليل الإحصائي، ويوفر أيضًا لغة برمجة متخصصة تسمى SPSS Syntax. يتيح هذه اللغة تنفيذ الإجراءات الإحصائية عن طريق كتابة الأوامر للمستخدمين، مما يوفر بديلاً لواجهة المستخدم الصورية. الغرض من هذا البحث هو إنشاء مربعات حوار جديدة مكتوبة بلغة SPSS Syntaxوباستخدام منشئ الحوار المخصص للملحقات. تم تصميم مربعات الحوار هذه لاختبار البيانات متعددة المتغيرات ذات العينة الواحدة أو العينتين عندما تكون ∑ غير معلومة من خلال تطبيق اختبار هوتيلينك T2، خاصة في حالة إفتقار واجهة المستخدم الصورية إلى هذه الوظائف المحددة. في حالة البيانات المكونة من عينتين، يتم استخدام طرق اختبارات متعددة المتغيرات المستقلة والمرتبطة أو والمزدوجة. تم تزويد أمثلة لتوضيح التحليلات الرئيسية التي تم إجراؤها باستخدام اختبارات T2. تم تنفيذ كتابة البرنامج لعمل التحليلات باستخدام برنامج SPSS v.27. يوصى باعتماد مربعات الحوار المطورة للباحثين الذين هم بحاجة إلى تحليل بيانات متعددة المتغيرات لعينة واحدة أو عينتين مع خبرة برمجية محدودة أو معدومة، مع إمكانية دمج مربعات الحوار بالمستقبل في إصدارات SPSS القادمة بواسطة IBM. توسيع نطاق التحليلات الإحصائية المدعومة بمربعات حوار SPSS من خلال عمل أبحاث مستقبلية تشجع استخدامها، وتدعم قبولًا أكبر لأساليب إحصائية أخرى غير موجودة في إصدارات SPSS الاعتيادية..
المراجع
Fujikoshi, Y., Ulyanov, V. V., and Shimizu, R., (2010), Multivariate Statistics: High‐Dimensional and Large‐Sample Approximations, JOHN WILEY & SONS.
IBM Corp., (2017), "IBM SPSS Statistics 25 Command Syntax Reference," IBM Corporation. [Online].Available: https://www.ibm.com/docs/SSLVMB_25.0.0/pdf/en/IBM_SPSS_Statistics_Command_Syntax_Reference.pdf.
IBM Corp., (2020), IBM SPSS Statistics for Windows, Armonk, NY. [Online] Available: https://www.ibm.com/support/pages/node/1101369
IBM Corp., (2023), "IBM SPSS Modeler Extensions,”. [Online] Available: https://www.ibm.com/docs/en/SS3RA7_18.3.0/pdf/ModelerExtensions.pdf.
Johnson, R. A., & Wichern, D. W., (2014), Applied Multivariate Statistical Analysis, Prentice Hall, 6th ed.
Pardoe, I., (2020), Applied Regression Modeling, John Wiley & Sons, 3rd ed.
Process, (2023), "Installing the PROCESS Custom Dialog in SPSS ,". [Online] Available: https://www.processmacro.org/uploads/3/4/8/5/34858384/dialoginstall.pdf.
Raykov, T., and Marcoulides, G. A., (2008), Introduction to applied multivariate analysis, Taylor & Francis Group.
Rencher, A., and Christensen, W. F., (2012), Methods of Multivariate Analysis, John Wiley & Sons, 3rd ed.
Srivastava, M. S., (2002), Methods of multivariate Statistics, New York: Wiley-Interscience.
Appendix
TITLE Test of Multivariate One Sample.
SET PRINTBACK=off.
Compute one=1.
Matrix.
get x
/variables=%%First_group%%
/missing=accept
/sysmis=omit.
get mu
/variables=%%Mu%%
/missing=accept
/sysmis=omit.
get one
/variables=one
/missing=accept
/sysmis=omit.
compute n=nrow (x).
compute p=ncol (x).
compute xbar=transpos(one)*x/n.
compute xbar_mat=one*xbar.
compute x_xbar=x-xbar_mat.
compute var_x=(transpos(x_xbar)*x_xbar)/(n-1).
compute inv_var_x=inv(var_x).
compute hotelling_t2=n*transpos(transpos(xbar)-mu)*inv_var_x*(transpos(xbar)-mu).
compute p_value=SIG.F(((n-p)/((n-1)*p))*hotelling_t2,p,n-p).
print mu / title "Mu zero".
print n / title "Number of Rows".
print p / title "Number of columns".
print xbar / title "X bar" /format f8.3.
print var_x/ title "Variance of X Matrix" /format f8.3.
print inv_var_x/ title "Inverse of Var-Covar Matrix" /format f8.3.
print hotelling_t2/ title "Hotelling's T2".
print p_value/ title "P-Value of the T2".
End Matrix.
Delete variables one.
**********************************************************************
TITLE Test of Multivariate Independent Two Samples.
SET PRINTBACK=off.
compute one=1.
Matrix.
get T1
/variables=%%First_group%%
/missing=accept
/sysmis=omit.
get T2
/variables=%%Second_group%%
/missing=accept
/sysmis=omit.
get one
/variables=one
/missing=accept
/sysmis=omit.
COMPUTE n1=nrow(t1).
COMPUTE n2=nrow(t2).
COMPUTE p=ncol(t1).
COMPUTE T1bar=transpos(one)*t1/n1.
COMPUTE T2bar=transpos(one)*t2/n2.
COMPUTE T1_T2=T1bar-T2bar.
compute T1bar_mat=one*T1bar.
compute T2bar_mat=one*T2bar.
compute T1_T1bar=T1-T1bar_mat.
compute T2_T2bar=T2-T2bar_mat.
compute var_T1=(transpos(T1_T1bar)*T1_T1bar)/(n1-1).
compute var_T2=(transpos(T2_T2bar)*T2_T2bar)/(n2-1).
compute Sp=1/(n1+n2-2)*((n1-1)*var_T1+(n2-1)*var_T2).
compute inv_sp=inv(Sp).
compute hotelling_t2=((n1*n2)/(n1+n2))*(T1_T2*inv_sp*(transpos(T1_T2))).
compute p_value=SIG.F(((n1+n2-p-1) / ((n1+n2-2)*p))*hotelling_t2,p,n1+n2-p-1).
print n1 / title "Number of rows in sample 1".
print n2 / title "Number of rows in sample 2".
print p / title "Number of variables".
print T1bar /title"Mean vector of First Sample"/format f8.3.
print T2bar /title"Mean vector of Second Sample"/format f8.3.
print var_T1 / title "VARINCE MATRIX of First Sample"/format f8.3.
print var_T2 / title "VARINCE MATRIX of Second Sample"/format f8.3.
print Sp / title "Pooled Variance Covariance Matrix"/format f8.3.
print inv_sp/ title "Inverse of Pooled Variance Covariance Matrix"/format f8.3.
print hotelling_t2/ title "Hotelling T2 Test".
print p_value/ title "P-Value of the Hotelling T2".
End matrix.
Delete variables one.
**********************************************************************
TITLE Test of Multivariate Paired Two Samples.
SET PRINTBACK=off.
compute one=1.
Matrix.
get T1
/variables=%%First_group%%
/missing=accept
/sysmis=omit.
get T2
/variables=%%Second_group%%
/missing=accept
/sysmis=omit.
get one
/variables=one
/missing=accept
/sysmis=omit.
compute d = T1-T2.
compute n=nrow (d).
compute p=ncol (d).
compute dbar=t(one)*d/n.
compute dbar_mat=one*dbar.
compute d_dbar=d-dbar_mat.
compute var_d=(t(d_dbar)*d_dbar)/(n-1).
compute inv_var_d=inv(var_d).
compute hotelling_t2=n*dbar*inv_var_d*t(dbar).
compute p_value=SIG.F(((n-p)/((n-1)*p))*hotelling_t2,p,n-p).
print n / title "Number of Rows".
print p / title "Number of columns".
print dbar / title "d bar" /format f8.3.
print var_d/ title "Variance of d Matrix" /format f8.3.
print inv_var_d/ title "Inverse of Var-Covar Matrix d"/format f8.3.
print hotelling_t2/ title "Hotelling's T2" /format f8.3.
print p_value/ title "P-Value of the T2" /format f8.3.
End Matrix.
Delete variables one.
التنزيلات
منشور
إصدار
القسم
الرخصة
مجلة الإدارة والاقتصاد هي مجلة مفتوحة المصدر حيث تكون جميع محتوياتها مجانية. تخضع مقالات هذه المجلة لشروط ترخيص المشاع الإبداعي المنسوب إلى المؤلف (CC-BY 4.0) (https://creativecommons.org/licenses/by/4.0/legalcode) الذي يسمح للمرخص لهم دون قيود بالبحث عن النص الكامل للمقالات أو تنزيله أو مشاركته أو توزيعه أو طباعته أو ربطه به، وفحصه للفهرسة وإعادة إنتاج أي وسيلة للمقالات بشرط أن ينسبوا إلى المؤلفين الفضل في ذلك (الاستشهاد). تسمح المجلة للمؤلفين بالاحتفاظ بحقوق الطبع والنشر لمقالهم المنشور.
. Creative Commons-Attribution (BY) 
